●トランスフォームの乗算について１

オブジェクトのトランスフォームに、
自身の反転したトランスフォームを右から掛けると、
原点に移動し、スケールと回転はリセットされる。

↓ $Teapot001.transform = $Teapot001.transform * inverse $Teapot001.transform

●トランスフォームの乗算について２

回転させていないオブジェクトAが原点にある。そのAのトランスフォームに、
原点から離れたオブジェクトBのトランスフォームを右から掛けると、
オブジェクトAは、オブジェクトBに位置と向きが揃う。スケールは乗算される。

例
ティーポット赤と緑のスケールは[1,1,2]（ [X軸,Y軸,Z軸] ）

↓　$TeapotRed.transform = $TeapotRed.transform * $TeapotGreen.transform
　結果：ティーポット赤のスケールは[1,1,4]になる。

※乗算する順番は重要。
基準にしたいオブジェクトのトランスフォームは右から(後から)掛ける。
スケールを編集している場合は、計算の結果が意図通りにならなくなる。

スケールが歪む例１：
○：ティーポット緑のトランスフォームを右から掛けた
×：ティーポット緑のトランスフォームを左から掛けた

○：ティーポット赤のスケールは[1,1,4]
×：ティーポット赤のスケールは[1,1.08118,3.69966]

スケールが歪む例２：
ティーポット青はローカルX方向、
ティーポット緑はローカルZ方向にスケールを編集してある。
↓初期状態

↓初期状態から、適切な乗算
　$TeapotBlue.transform = $TeapotBlue.transform * $TeapotGreen.transform
　ティーポット緑のスケールが[1,1,2]、
　ティーポット青のスケールが[2,1,1]の場合
　計算したあと、ティーポット青のスケールは[2,1,2]になる。

↓初期状態から、適切でない乗算
　$TeapotBlue.transform = $TeapotGreen.transform * $TeapotBlue.transform
　歪んでしまった

●Autodesk 3dsMax公式ヘルプへのリンク
Matrix3 値

赤い矢印の向く方向を軸にして、
複数のティーポットを毎フレーム10度回転させている。

Cylinder001という名前の円柱を作る。
回転させたいオブジェクトを複数作成する。
回転させたい物を全部選択して、↓のスクリプトを実行する。

with redraw off(
with animate on(
	kaiten = quat 10 $Cylinder001.dir
	kaiten = kaiten as matrix3

	for i=1 to 36 do(
		slidertime = i
		for tea in selection do(
			iti = tea.pos
			tea.transform *= kaiten
			tea.pos = iti
		)
	)
)
)

エラーがなければ、円柱の向く方向を軸にして、
選択したオブジェクトが毎フレーム10度回転するアニメーションが作成される。

with redraw off(
with animate on(
	for kyuusu in selection do(
		for i=1 to 36 do(
			slidertime = i
			iti = kyuusu.pos
			kaiten = quat 10 kyuusu.dir
			kaiten = kaiten as matrix3
			kyuusu.transform *= kaiten
			kyuusu.pos = iti
		)
	)
)
)

●使い方
回転させたいオブジェクトを選択して、↑のスクリプトを実行。
※コピペはMAXScriptリスナーではなく、MAXScriptエディタへ。
　リスナーでは複数行のコードを実行できない。

●処理内容
選択したオブジェクトそれぞれのローカルZ軸を中心にして、
10度の回転をフレーム毎に行う。

●説明
・　with redraw off()：
このカッコ内のスクリプト実行中はビューが更新されない。

・　with animate on()：
このカッコ内のスクリプトによる変更はキーが打たれる。

・　for：
forループ文

・　iti = kyuusu.pos：
変数itiにオブジェクトの位置を入れる。

・　kaiten = quat 10 kyuusu.dir：
オブジェクトのローカルZを軸とした10度の回転を、
quat値で変数kaitenに入れる。

・　kaiten = kaiten as matrix3
変数kaitenに入ったquat値をmatrix3値に変換して、
変数kaitenに入れる。

・　kyuusu.transform *= kaiten
オブジェクトのトランスフォーム(matrix3値)に、
変数kaitenに入ったmatrix3値を乗算する。

・　kyuusu.pos = iti：
オブジェクトの位置を、変数itiに入った値にする。

●3dsMax公式ヘルプへのリンク
スクリプトでのプログラム フロー制御
For ループ
ノード変換プロパティの使い方
Quat 値
Matrix3 値

位置、回転、スケールを別々のオブジェクトから取り出し、合成する。
実行後の白ティーポットは赤の位置、緑の回転、青のスケールで構成されている。

赤ティーポットからは位置を取得
緑ティーポットからは回転を取得
青ティーポットからはスケールを取得

変換行列　＝　スケール行列 × 回転行列 × 位置

白ティーポットに合成した変換行列を割り当てる

iti = transMatrix $teapot01.pos --赤ティーポット
kaiten = (inverse $teapot02.rotation) as matrix3 --緑ティーポット
kakusyuku = scaleMatrix $teapot03.scale --青ティーポット

gousei =  kakusyuku * kaiten * iti
$teapot04.transform = gousei --白ティーポット

●公式ヘルプへのリンク
AUTODESK 3DS MAX 2017　ヘルプ
ノード変換プロパティの使い方
Matrix3 値

選択した複数のオブジェクトの向きを、
ある任意のオブジェクトの向きと一致させようとして、
↓のスクリプトを実行したら、オブジェクトが意図しない位置へ移動してしまった。

for i in selection do(
	i.rotation = $teapot001.rotation
)

向きは合っているけど、位置がおかしい。

位置を保持し、向きを合わせてから、元の位置へ戻すようにした。

for i in selection do(
	iti = i.pos
	i.rotation = $teapot001.rotation
	i.pos = iti 
)

意図通り、位置はそのままに、向きだけが合う様になった。

↓の処理でも同じ結果になる。

for i in selection do(
	iti = transMatrix i.pos
	kaiten = inverse($teapot01.rotation as matrix3)
	i.transform = kaiten * iti
)

↓回転させるティーポットが全部同じ向きなら、原点を基準に回転しているのが分かる。
(回転の中心のティーポットが原点に居るやつ)

↓向きがバラバラだと回転の規則性が分かりにくい。

↓位置を維持する処理